Arduino网络编程实战-Ethernet篇-WebSocket服务器

WebSocket服务器

Arduino Ethernet Shield V1 允许 Arduino 板连接到互联网。它基于 Wiznet W5100ethernet 芯片（数据表）。 Wiznet W5100 提供支持 TCP 和 UDP 的网络 (IP) 堆栈。它最多支持四个同时套接字连接。

本次实例将演示如何实现一个简单的Websocket服务器。

1、硬件准备

Arduino Mega 2560
Arduino Ethernet Shield
路由器（推荐可以上网、开启DHCP）
网线一条
电脑一台

2、软件准备

Arduino IDE
网络调试软件（推荐使用通信猫)
支持库：https://github.com/skaarj1989/mWebSockets
Nodejs
Nodejs支持库：https://github.com/websockets/ws

3、代码实现

1）Arduino的WebSocket服务器实现

#include <SPI.h>
#include <Ethernet.h>
#include <Arduino.h>
#include <WebSocketServer.h>
using namespace net;
#define USE\_STATIC 0
byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};
#if USE\_STATIC
IPAddress ip(192, 168, 0, 177);
#endif

constexpr uint16\_t port = 3000;
WebSocketServer wss{port};

void setup() {
  
   Serial.begin(9600);
   Serial.println("Ethernet Websocket Server Example");
   
#if USE\_STATIC
   Ethernet.begin(mac,ip);
#else
  Ethernet.begin(mac);
#endif

   if (Ethernet.hardwareStatus() == EthernetNoHardware) {
    Serial.println("Ethernet shield was not found. Sorry, can't run without hardware. :(");
    while (true) {
      delay(1); 
    }
  }
  if (Ethernet.linkStatus() == LinkOFF) {
    Serial.println("Ethernet cable is not connected.");
    while(true){
      delay(1);  
    }
  }

  Serial.print("IP:");
  Serial.println(Ethernet.localIP());
  Serial.print("Subnet Mask:");
  Serial.println(Ethernet.subnetMask());
  Serial.print("Gateway:");
  Serial.println(Ethernet.gatewayIP());
  Serial.print("DNS Server:");
  Serial.println(Ethernet.dnsServerIP());


 wss.onConnection([](WebSocket &ws) {
    const auto protocol = ws.getProtocol();
    if (protocol) {
      Serial.print(F("Client protocol: "));
      Serial.println(protocol);
    }

    ws.onMessage([](WebSocket &ws, const WebSocket::DataType dataType,
                   const char \*message, uint16\_t length) {
      switch (dataType) {
      case WebSocket::DataType::TEXT:
        Serial.print(F("Received: "));
        Serial.println(message);
        break;
      case WebSocket::DataType::BINARY:
        Serial.println(F("Received binary data"));
        break;
      }

      ws.send(dataType, message, length);
    });

    ws.onClose([](WebSocket &, const WebSocket::CloseCode, const char \*,
                 uint16\_t) { Serial.println(F("Disconnected")); });

    Serial.print(F("New client: "));
    Serial.println(ws.getRemoteIP());

    const char message[]{"Hello from Arduino server!"};
    ws.send(WebSocket::DataType::TEXT, message, strlen(message));
  });

  // 启动WebSocket服务器
  wss.begin();
}

void loop() {
   wss.listen(); // 监听连接
}

2）Nodejs的Websocket客户端实现

const WebSocket = require("ws");

const ws = new WebSocket('ws://192.168.0.106:3000/');

ws.on('open', function open() {
  ws.send('Hello,Arduino Mega2560!');
});

ws.on('message', function message(data) {
  console.log('received: %s', data);
});