Arduino网络编程实战-Ethernet篇-Websocket客户端

Websocket客户端

Arduino Ethernet Shield V1 允许 Arduino 板连接到互联网。它基于 Wiznet W5100ethernet 芯片（数据表）。 Wiznet W5100 提供支持 TCP 和 UDP 的网络 (IP) 堆栈。它最多支持四个同时套接字连接。

本次实例将演示如何实现一个简单的Websocket客户端。

1、硬件准备

Arduino Mega 2560
Arduino Ethernet Shield
路由器（推荐可以上网、开启DHCP）
网线一条
电脑一台

2、软件准备

Arduino IDE
网络调试软件（推荐使用通信猫)
支持库：https://github.com/skaarj1989/mWebSockets
Nodejs
Nodejs支持库：https://github.com/websockets/ws

3、代码实现

1）Arduino的Websocket客户端实现

#include <SPI.h>
#include <Ethernet.h>
#include <Arduino.h>
#include <WebSocketClient.h>
using namespace net;
#define USE\_STATIC 0
byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};
#if USE\_STATIC
IPAddress ip(192, 168, 0, 177);
#endif

WebSocketClient client;

void setup() {
  
   Serial.begin(9600);
   Serial.println("Ethernet Websocket Client Example");
   
#if USE\_STATIC
   Ethernet.begin(mac,ip);
#else
  Ethernet.begin(mac);
#endif

   if (Ethernet.hardwareStatus() == EthernetNoHardware) {
    Serial.println("Ethernet shield was not found. Sorry, can't run without hardware. :(");
    while (true) {
      delay(1); 
    }
  }
  if (Ethernet.linkStatus() == LinkOFF) {
    Serial.println("Ethernet cable is not connected.");
    while(true){
      delay(1);  
    }
  }

  Serial.print("IP:");
  Serial.println(Ethernet.localIP());
  Serial.print("Subnet Mask:");
  Serial.println(Ethernet.subnetMask());
  Serial.print("Gateway:");
  Serial.println(Ethernet.gatewayIP());
  Serial.print("DNS Server:");
  Serial.println(Ethernet.dnsServerIP());


 client.onOpen([](WebSocket &ws) {
    Serial.println(F("Connected"));
    const auto protocol = ws.getProtocol();
    if (protocol) {
      Serial.print(F("Client protocol: "));
      Serial.println(protocol);
    }

    const char message[]{"Hello from Arduino client!"};
    ws.send(WebSocket::DataType::TEXT, message, strlen(message));
  });

  client.onMessage([](WebSocket &ws, const WebSocket::DataType dataType,
                     const char \*message, uint16\_t length) {
    switch (dataType) {
    case WebSocket::DataType::TEXT:
      Serial.print(F("Received: "));
      Serial.println(message);
      break;
    case WebSocket::DataType::BINARY:
      Serial.println(F("Received binary data"));
      break;
    }

    ws.send(dataType, message, length); // Echo back to server
  });

  client.onClose([](WebSocket &, const WebSocket::CloseCode, const char \*,
                   uint16\_t) { Serial.println(F("Disconnected\n")); });

  if (!client.open("192.168.0.100", 3000, "/")) {
    Serial.println(F("Connection failed!"));
    while (true)
      ;
  }
  Serial.println("connected to websocket server");
}

void loop() {
   client.listen();
}

2）Nodejs的Websocket服务器实现

// simple-ws-server.js
const WebSocket = require("ws");

const wss = new WebSocket.Server({
  host: "0.0.0.0",
  port: 3000,
});

wss.on("connection", (ws, req) => {
  ws.remoteAddress = req.socket.remoteAddress.replace(/^.\*:/, "");
  console.log(`new client: ${ws.remoteAddress}`);

  ws.on("message", (message) => {
    console.log(`[${ws.remoteAddress}] > ${typeof message}:`, message);
  });
  ws.on("close", (code, reason) => {
    console.log(
      `[${ws.remoteAddress}] client disconnected: ${code} "${reason}"`
    );
  });
  ws.on("error", (err) => console.log(`[${ws.remoteAddress}] error:`, err));
  ws.on("ping", () => console.log(`[${ws.remoteAddress}] > ping`));

  ws.send("Hello from Node.js");

  setTimeout(() => {
    console.log(`disconnecting ${ws.remoteAddress} ...`);
    ws.close();
  }, 60000);
});

wss.on("listening", () => {
  let remote = wss.address();
  console.log(`Server running at ${remote.address}:${remote.port}`);
});